| 首页 | 文章 | 下载 | 图片 | 论坛 | 留言 |  自选风格 |
 
 
 您现在的位置： 晨光科技 >> 文章 >> 技术 >> 单片机 >> 正文  
  制作自动驾驶和避让的迷你遥控车，基于ESP32的Arduino开发模块           
制作自动驾驶和避让的迷你遥控车，基于ESP32的Arduino开发模块
［ 作者：佚名    转贴自：https://mbb.eet-china.com/forum/topic/125529_1_1.html    点击数：32    更新时间：2023/6/28    文章录入：LA ］
[注：本站登载的某些文章并不代表本站支持或反对其观点或肯定其真实性]
制作自动驾驶和避让的迷你遥控车，基于ESP32的Arduino开发模块 techff  590  0 发表于 2023-3-1 15:34:07 只看该作者倒序浏览 用Arduino兼容设备（M5Stack）和传感器制作迷你遥控车 

第1部分：用小型Arduino兼容设备（M5Stack）享受电子制作的乐趣
第2部分：通过M5Stack使用电机驱动器
第3部分：通过M5Stack使用传感器实现自动驾驶和自动避让功能
剧终篇：实现M5Stack与智能手机联动控制 

第一部分
这次我想用小型Arduino兼容设备“M5Stack”系列来制作一辆原创遥控车。这里使用的M5Stack是一种使用了ESP32的Arduino开发模块，自带传感器和显示器等配件，使用它可以轻松开始开发。我想为大家介绍一下使用这种M5Stack制作也可以从外部控制的迷你遥控车的过程。
 
本部分的流程
  • 关于Arduino兼容设备M5Stack系列
  • 制作本设备所需的部件
  • 遥控车的功能和可以学到的知识
  • M5Stack开发环境安装
  • 总结

1. 关于Arduino兼容设备M5Stack系列
M5Stack是由中国深圳硬件初创公司M5Stack推出的Arduino兼容开发模块之一。它使用Espressif公司内置有Wi-Fi和BLE的ESP32平台，使开发变得像Arduino一样简单。其特点是在小小的产品中，自带显示器、传感器、按钮、USB接口等。
M5Stack有多个系列，用户可以根据大小和用途进行选择。最容易上手的是“M5 Stack Core”，它带有较大的方形显示器。另外还有“M5 Stick-C”，它的外壳和显示器尺寸更小，更易于使用。2020年还推出了大概只有“M5 Stick-C”一半大小的超小型“ATOM”系列。
 
M5Stack Core 
M5Stick-C 
M5Stack ATOM Matrix
下表中将这几种产品的规格简单汇总了一下。请根据用途和尺寸选用。
系列 M5Stack M5Stick M5Stack ATOM
名称 M5Stack Core Gray M5Stick-C M5Stack ATOM Matrix
芯片 ESP32-D0WDQ6
(Wifi, BLE)		 ESP32-P IC O
(Wifi, BLE)		 ESP32-PICO
(Wifi, BLE)
存储器 520KB RAM
16MB Flash		 520KB RAM
4MB Flash		 520KB RAM
4MB Flash
大小 5.4 x 5.4 x 1.7 cm 4.8 x 2.5 x 1.4 cm 2.4 x 2.4 x 1.4 cm
显示器 Color TFT LCD (2 inch) Color TFT LCD (0.96 inch) 5 x 5 RGB LCD
传感器类 MPU6886（加速度传感器）
BMM150（地磁传感器）
无麦克风
有扬声器		 MPU6886（加速度传感器）
红外LED
有麦克风
无扬声器		 MPU6886（加速度传感器）
红外LED
无麦克风
无扬声器
电池 150mAh @3.7V 80mAh @3.7V 无
参考价格 4,800日元左右 2,000日元左右 2,000日元左右

2. 制作本设备所需的部件
这次我们将使用M5Stack和一些传感器来创建可以自动驾驶或远程控制的小型汽车，所需部件汇总如下。
车身部分
名称和说明 部件
M5Stack Core
搭载了ESP32的Arduino兼容设备。不仅自带大型LED显示器，还自带BLE、Wifi和运动传感器等。
超声波距离传感器
发射超声波并通过其反弹声波来测量距离的模块。
ROHM照度/接近传感器
(RPR-0521RS)
(RPR-0521RS)
通过发射红外线并测量其反射光来测量光的强度和接近度。
Grove I2C电机驱动器
使用称为“I2C”的通信方式，与Grove引脚连接即可使用的电机驱动器。
车轮、外装件等
遥控部分：
名称和说明 部件和应用
M5Stick-C
在M5Stack系列中尺寸更小的产品，具有BLE和Wi-Fi功能的ESP32 Arduino兼容模块
Blynk（智能手机应用程序）
可以通过Wi-Fi操作Arduino和Raspberry Pi的智能手机应用程序。
把这些部件备好后，就可以制作小型遥控车了。

3. 遥控车的功能和可以学到的知识
这次要做的遥控车分为汽车车身部分和遥控部分两部分。车身部分将使用传感器自动行驶。遥控器使用M5Stcick-C和智能手机来实现对汽车的控制。下面列出了车身部分和遥控部分可以实现的功能，以及可以学到的知识。
车身部分：
编号 可以学到的知识
1 使用Arduino IDE开发M5Stack的方法
2 使用I2C电机驱动器、通过Arduino控制电机来制作小汽车的方法
3 使用了距离传感器的物体避让机制
4 使用照度/接近传感器而不会从桌子上等高处掉下来的机制
遥控部分
编号 可以学到的知识
1 使用M5Stack时的运动传感器使用方法
2 Arduino（M5Stack）之间通过BLE进行通信和操作的方法
3 从智能手机上操作Arduino（M5Stack）的方法

4. M5Stack开发环境安装
要想使用Arduino IDE进行M5Stack程序开发，需要进行一些必要的准备工作。请前往Arduino IDE下载页面（https://www.arduino.cc/en/main/software）下载并安装软件。另外，最好提前了解一下ESP-WROOM-32的使用方法。
 
[Arduino IDE的下载界面 https://www.arduino.cc/en/main/software ]Arduino IDE安装完成后，需要设置ESP32开发板。从Arduino的菜单中，选择设置 > Preferencees，并在“ Additional Boards Manager URL”中输入以下地址：
https://dl.espressif.com/dl/package_esp32_index.json
 
然后通过Tools > Boards > Boards Manager搜索ESP32并安装开发包。
 
这样就可以选择M5Stack-Core-ESP32作为开发板了，请选择它。此外，从串口指定USB连接并连接电脑和M5Stack。
 
另外，还需要通过Sketch > Include Library > Manage Library管理来添加M5Stack的库。
 
现在，让我们用USB-C数据线连接电脑和M5Stack吧。刚刚下载的M5Stack库中附有一些示例程序，我们可以直接使用。从File > Sketch example > M5Stack中选择示例草图并将其导入。
 
 
[左起分别是：M5Stack Core Gray、M5Stcik-C、M5Stack ATOM Matrix]
5. 总结
在本系列连载中，我们将使用M5Stack制作遥控车。M5Stack系列有自带传感器的产品，也有带较大显示器的产品，请根据您的用途选用。传感器也可以从外部安装，因此还可以通过添加ROHM的传感器等器件来增加功能。
从下一部分开始，我将为大家介绍实际制作遥控车的过程，敬请期待！

（第二部分）

通过M5Stack使用电机驱动器

本系列连载将为您介绍使用小型Arduino兼容设备M5Stack制作遥控车的过程。在第二部分中，我们将连接M5Stack和电机驱动器，以使直流电机运转。由于使用一个名为“Grove”的标准引脚，而使看似复杂的电机驱动器设置变得非常简单。
 
使用M5Stack系列制作遥控车
本部分的流程
  • 电机驱动器的设置
  • M5Stack与电机的连接
  • 运行M5Stack的程序
  • 总结

本部分所需部件
M5Stack Core
搭载了ESP32、显示器、传感器等的Arduino兼容设备
 
Grove I2C电机驱动器
使用“I2C”通信方式与Grove引脚连接即可使用的电机驱动器
 
9V电池和电池盒
 
小型电机、车轮等
 

1. 电机驱动器的设置
在制作迷你遥控车时，需要一个称为“电机驱动器”的IC器件来负责驱动直流电机并控制转速等工作。电机驱动器与Arduino之间的连接以及编程稍微有点复杂，但是M5Stack带有Grove引脚，通过使用可以与Grove相连接的电机驱动器，即可轻松进行电机控制。
这次我们将使用带有Grove引脚的、I2C控制方式的这款电机驱动器。
 
需要进入开发这款电机驱动器的SEEED公司的产品页面，并获取库文件。请单击下面页面中的Grove I2C Motor Driver，将其下载到您的计算机上。
https://wiki.seeedstudio.com/Grove-I2C_Motor_Driver_V1.3/
 
从菜单上的Sketch > Include library > Add .ZIP Library中选择前面提到的文件并应用。
 
现在已安装好了库和示例草图。在草图示例菜单中有一个名为“dcmotor_test”的示例，选择它并将其写入M5Stack。
 
需要连接电脑、M5Stack 和电机驱动器之后进行写入。当出现如画面中的消息时，表明电机驱动器的草图已经成功写入。
 
2. M5Stack与电机的连接
将直流电机连接到M5Stack和电机驱动器。对于驱动部分，我们使用车轮已经与非常小的电机连接好的齿轮电机。将这个齿轮电机固定到电池盒上，很容易就实现了一体化的迷你遥控车。
 
电机和车轮设置
 
将电机和电池盒固定（用螺丝拧紧）
将电机出来的2对线缆、电池盒出来的1对线缆分别与电机驱动器连接。
 
连接电机侧的引脚
 
连接 电源 侧的引脚
现在，电机驱动器、车轮和电池盒是这样的：
 
在M5Stack侧也要安装小车轮。使用Grove线缆连接电机驱动器和M5Stack。
 
整体如下：
 

3. 运行M5Stack的程序
最后，我们需要创建程序来运行M5Stack。M5Stack有一个显示器，所以我们让遥控车行驶过程中在屏幕上显示相应的内容。示例程序M5_Motor.ino如下：
  1. #include "Grove_I2C_Motor_Driver.h"
  2. #include <M5Stack.h>
  3. #define I2C_ADDRESS 0x0f

  5. void setup() {
  6.     Serial.begin(9600);
  7.     Motor.begin(I2C_ADDRESS);

  9.     M5.begin();
  10.     M5.Lcd.setTextSize(4);
  11.     M5.lcd.print("GO M5!");
  12. }

  14. void loop() {
  15.     // Set speed of MOTOR1, Clockwise, speed: -100~100
  16.     Motor.speed(MOTOR1, 100);
  17.     // Set speed of MOTOR2, Anticlockwise
  18.     Motor.speed(MOTOR2, -100);
  19.     M5.lcd.clear();
  20.     M5.Lcd.setCursor(10,0);
  21.     M5.lcd.print("GO M5!");
  22.     M5.Lcd.setCursor(10,60);
  23.     M5.lcd.print("Forward!");
  24.     delay(2000);
  25.     // Change speed and direction of MOTOR1
  26.     Motor.speed(MOTOR1, -100);
  27.     // Change speed and direction of MOTOR2
  28.     Motor.speed(MOTOR2, 100);
  29.     M5.Lcd.setCursor(10,60);
  30.     M5.lcd.print("Backward!");
  31.     delay(2000);
  32.     // Stop MOTOR1 and MOTOR2
  33.     Motor.stop(MOTOR1);
  34.     Motor.stop(MOTOR2);
  35.     M5.lcd.clear();
  36.     M5.Lcd.setCursor(10,60);
  37.     M5.lcd.print("Stop!");
  38.     delay(2000);
  39. }
程序准备好后，将其导入 M5Stack。打开电源后，车轮应该开始转动了。
 

向前转动时显示“Forward”，向后转动时显示“Backword”。
 
 

4. 总结
这次我们用两个小型齿轮电机实现了前后左右行驶。虽然需要用电机驱动器来控制Arduino和直流电机，不过我想您已经了解到了，只需将其与Grove引脚连接即可轻松开始使用。
M5Stack的Grove引脚可以连接各种驱动器和传感器等，因此您还可以尝试连接其他传感器。
在下一部分中，我们将通过安装距离传感器等器件，来实现避让墙壁、避免从桌子上掉下来等目标。自动驾驶即将实现，敬请期待！

(第三部分)


通过M5Stack使用传感器实现自动驾驶和自动避让功能

本系列连载将为您介绍使用小型Arduino兼容设备M5Stack制作遥控车的过程。这次我们将在M5Stack上添加各种传感器，以便实现自动控制。M5Stack有很多引脚，因此仅需插入接近传感器或距离传感器即可轻松增加相应的功能。
 
 
在M5Stack上安装距离传感器和接近传感器，实现自动驾驶
本部分的流程
  • 照度、接近一体型传感器的设置
  • 距离传感器的设置
  • 用传感器进行测量，同时自动驾驶
  • 总结

本部分所需部件M5Stack Core
搭载了ESP32、显示器、传感器等的Arduino兼容设备
 

ROHM的照度、接近一体型传感器 (RPR-0521RS)
通过发射红外光并测量其反射光来测量光强和接近程度。
 
超声波距离传感器 (HC-SR04)
发射超声波并通过其反弹声波来测量距离的模块。
 
Grove I2C电机驱动器
使用“I2C”通信方式与Grove引脚连接即可使用的电机驱动器
 
9V电池和电池盒
 
小型电机、车轮等
 

1. 照度、接近一体型传感器的设置
我希望遥控车在行驶时，在即将撞到障碍物或即将从桌子上掉下来的情况下，能够自动避让并避免掉落。
首先，我们使用接近传感器来判断是否即将掉落。接近传感器我们用ROHM传感器评估套件中的照度、接近一体型传感器模块（RPR-0521RS）。
 
该传感器通过发射红外LED光并检测其反射光来测量物体等的接近程度。另外，还可以通过亮度传感器来同时测量亮度。
要使用该传感器，需要进入下面的ROHM传感器页面并下载Arduino用的库。
https://www.rohm.com.cn/sensor-shield-support/ps-als-sensor
在ROHM官网上下载zip文件后，通过其菜单安装Arduino IDE库。
 
接下来，我们把M5Stack和传感器连接起来。M5Stack上下有8个引脚，左右有15个引脚，背面写有引脚排列编号。Arduino的GPIO（输入输出引脚）与数字标注的引脚编号相对应。
 
M5Stack背面的引脚排列图照度、接近一体型传感器使用“I2C”通信方式。我们用M5Stack下方引脚中的SDA=G21和SCL=G22进行I2C通信。请按照下表连接传感器和M5Stack。
传感器侧引脚
(右起)		 M5Stack侧
（下方）
VDO 3.3V (橙)
GND GND (蓝)
SDA GPIO21 (黄)
SCL GPIO22 (绿)
INT NA
 
传感器和M5Stack连接好之后，从Arduino IDE的草图示例中选择前面安装的示例PRP-0521RS。
添加到示例中之后还需要在M5Stack的显示器中显示等，所以要将其另存为“M5Stack_PRP-0521RS.ino”。在这里添加如下程序（第1、11〜14、20、29〜30、36、39行）。
是M5Stack用的库。Wire.begin(21,22)是为了使M5Stack能够使用I2C通信方式的声明。
[M5Stack_PRP-0521RS.ino]
  1. #include <M5Stack.h>
  2. #include <Wire.h>
  3. #include <RPR-0521RS.h>
  4. RPR0521RS rpr0521rs;

  6. void setup() {
  7.   byte rc;  
  8.   Serial.begin(115200);
  9.   while (!Serial);  

  11.   Wire.begin(21,22);
  12.   M5.begin();
  13.   M5.Lcd.setTextSize(2);
  14.   M5.Lcd.setRotation(3);

  16.   rc = rpr0521rs.init();
  17. }

  19. void loop() {
  20.   Wire.begin(21,22);
  21.   byte rc;
  22.   unsigned short ps_val;
  23.   float als_val;
  24.   byte near_far;

  26.   rc = rpr0521rs.get_psalsval(&ps_val, &als_val);
  27.   if (rc == 0) {
  28.     Serial.print(F("RPR-0521RS (Proximity)     = "));
  29.     M5.Lcd.setCursor(10, 20);
  30.     M5.Lcd.printf("RPR-0521RS: ");
  31.     Serial.print(ps_val);
  32.     Serial.print(F(" [count]"));
  33.     near_far = rpr0521rs.check_near_far(ps_val);
  34.     if (near_far == RPR0521RS_NEAR_VAL) {
  35.       Serial.println(F(" Near"));
  36.       M5.Lcd.printf("M5 Near!");
  37.     } else {
  38.       Serial.println(F(" Far"));
  39.       M5.Lcd.printf("M5 Far !");
  40.     }
  41.   }
  42.   delay(500);
  43. }
通过M5Stack使用该程序时，需要更改一项。打开文件“PRP-0521RS.cpp”并删除“#include”部分中的“avr/”（通常安装的库位于Arduino > Libraries > RPR-0521RS中）。进行该操作后，M5Stack就可以正常读取pgmspace.h了。
[PRP-0521RS.cpp的位置，更改前。删除红框部分的“avr/”。 ]
 
完成该更改后，运行“M5Stack_PRP-0521RS.ino”。将会开始自动测量，当您将手指靠近设备时，屏幕上会出现如图所示的“Near！”消息。
 
当手指靠近时，会输出“Near”来告知附近有东西
2. 距离传感器的设置
接下来，我们在M5Stack上安装距离传感器，以便能够检测出并避让障碍物。我们使用这种名为“HC-SR04”的超声波距离传感器。这是一种能够发射超声波并通过其反弹声波来测量距离的模块。
 
按照下表和照片所示连接该超声波传感器。
传感器侧引脚
(左起)		 M5Stack侧
（左侧侧面）
VCC 5V (红)
Trig GPIO2 (橙)
Echo GPIO5 (黄)
GND GND (黑)
 
驱动这个距离传感器的程序“M5Stack_Dist.ino”如下。由于G2与输出TRIG连接，G5与输入ECHO连接，因此程序中分别指定了GPIO编号。
  1. [M5Stack_Dist.ino]

  3. #include <M5Stack.h>
  4. #define TRIG 2
  5. #define ECHO 5

  7. int times;
  8. int distance;

  10. void setup() {

  12.   Serial.begin(115200);
  13.   while (!Serial);  

  15.   pinMode(TRIG, OUTPUT);
  16.   pinMode(ECHO, INPUT);

  18.   M5.begin();
  19.   M5.Lcd.setTextSize(2);
  20.   M5.Lcd.setRotation(3);
  21. }

  23. void loop() {

  25.   // 发射超声波
  26.   digitalWrite(TRIG, HIGH);
  27.   delayMicroseconds(10);
  28.   digitalWrite(TRIG, LOW);

  30.   // 接收超声波
  31.   times = pulseIn(ECHO, HIGH);
  32.   distance = (int)(times * 0.017);

  34.   // 在监视器、显示器上显示
  35.   Serial.println(distance);
  36.   M5.Lcd.setCursor(0, 0);
  37.   M5.Lcd.print(distance);
  38.   delay(500);
  39. }
运行该程序，当将手指靠近距离传感器时，就会测量出距离。该距离数据表示串口监视器和M5Stack屏幕与手等障碍物之间的距离。
 
在串口监视器（左）和M5Stack屏幕（右）上显示测量到的距离
3. 用传感器进行测量，同时自动驾驶
最后，要能够根据传感器的测量结果进行控制，以避让障碍物并避免从桌子上掉落下来。首先，我们需要将电机驱动器、车轮等连同传感器重新连接起来。将电机驱动器连接在Grove引脚上，将距离传感器设置在容易捕捉前方情况的位置，将接近传感器设置在下方。
 
还要创建一个使传感器和电机联动的程序。在程序中，当距离传感器测到距离小于5cm时，即判断为“附近有障碍物”。另外，当接近传感器测量到与地板之间的接近程度变为“Far”时，即判断为“即将从桌子边缘掉落”。此时，电机将会反转，以避免掉落（避让障碍物）。否则将继续前进。
示例程序“M5Stack_Near_Dist_Motor.ino”如下：
  1. #include <M5Stack.h>
  2. #include <Wire.h>
  3. #include <RPR-0521RS.h>
  4. RPR0521RS rpr0521rs;
  5. #define TRIG 2
  6. #define ECHO 5
  7. int times;
  8. int distance;
  9. #include "Grove_I2C_Motor_Driver.h"
  10. #define I2C_ADDRESS 0x0f
  11. void setup() {
  12. Serial.begin(115200);
  13. while (!Serial);
  14. byte rc;
  15. rc = rpr0521rs.init();
  16. pinMode(TRIG, OUTPUT);
  17. pinMode(ECHO, INPUT);
  18. Motor.begin(I2C_ADDRESS);
  19. Wire.begin(21,22);
  20. M5.begin();
  21. M5.Lcd.setTextSize(4);
  22. M5.Lcd.setCursor(10,0);
  23. M5.lcd.print("M5 Near Dist Motor");
  24. }
  25. void loop() {
  26. Wire.begin(21,22);
  27. byte rc;
  28. unsigned short ps_val;
  29. float als_val;
  30. byte near_far;
  31. M5.lcd.clear();
  32. M5.Lcd.setCursor(10,0);
  33. M5.lcd.print("M5 Near Dist Motor");
  34. M5.Lcd.setCursor(10,50);
  35. rc = rpr0521rs.get_psalsval(&ps_val, &als_val);
  36. if (rc == 0) {
  37. Serial.print(F("RPR-0521RS (Proximity) = "));
  38. Serial.print(ps_val);
  39. Serial.print(F(" [count]"));
  40. near_far = rpr0521rs.check_near_far(ps_val);
  41. if (near_far == RPR0521RS_NEAR_VAL) {
  42. Serial.println(F(" Near"));
  43. M5.lcd.print("Near!");
  44. } else {
  45. Serial.println(F(" Far"));
  46. M5.lcd.print("Far!");
  47. }
  48. }
  49. // 发射超声波
  50. digitalWrite(TRIG, HIGH);
  51. delayMicroseconds(10);
  52. digitalWrite(TRIG, LOW);
  53. // 接收超声波
  54. times = pulseIn(ECHO, HIGH);
  55. distance = (int)(times * 0.017);
  56. // 在显示器上显示
  57. Serial.println(distance);
  58. M5.Lcd.setCursor(10, 100);
  59. M5.Lcd.print(distance);
  60. M5.Lcd.setCursor(10,150);
  61. // 当距离小于6时，如果接近程度继续变大，将使电机反转
  62. if ( ((distance > 0) and (distance < 6)) or (near_far != RPR0521RS_NEAR_VAL) ) {
  63. Motor.speed(MOTOR1, 100);
  64. Motor.speed(MOTOR2, -100);
  65. delay(800);
  66. Motor.speed(MOTOR1, 100);
  67. Motor.speed(MOTOR2, 100);
  68. M5.lcd.print("Danger!");
  69. delay(800);
  70. } else {
  71. // 如果没有障碍物就继续前进
  72. Motor.speed(MOTOR1, -100);
  73. Motor.speed(MOTOR2, 100);
  74. M5.lcd.print("Forward!");
  75. }
  76. delay(300);
  77. }
程序准备好后，将其导入M5Stack。当您接通电源后，车轮将开始转动并向前行驶。请您确认一下，在遥控车遇到障碍物或要从桌子上掉落下来时，电机能否反转。
 

4. 总结
在这个连载系列中，将为您介绍使用M5Stack进行遥控并实现自动驾驶小车的制作过程。在第三部分中，我们使用距离传感器来确认了前方物体，并使用接近传感器来确认了接近情况。
我们还让这两种传感器和电机的旋转联动实现了自动驾驶。怎么样，效果还不错吧？由于还需要微调与障碍物之间的距离设置、反转时间等参数，因此您需要一边试用一边调整数值。
M5Stack仍然有可以使用的引脚，因此您还可以尝试添加其他传感器来实现相应的功能，这可能会更有趣。比如，可以让它在自由行驶的同时测量室内温度和空气清洁度。
在下一部分中，我们将介绍通过智能手机等从外部来控制遥控车的方法，敬请期待！

（剧终篇）

实现M5Stack与智能手机联动控制

本系列连载将为您介绍使用小型Arduino兼容设备M5Stack制作遥控车的过程。在前面的部分中，我们已经用电机驱动器让遥控车能够前后左右移动，并通过传感器实现了自动驾驶。在本文中，也就是本系列的最后一部分中，我们将实现从外部遥控这辆遥控车。这次，我们将会导入一种能够通过智能手机操作5Stack的名为“Blynk”的机制。
 
M5Stack和智能手机联动的遥控车
本部分的流程
  • 导入智能手机应用程序“Blynk”
  • 在Wi-Fi环境下通过智能手机操作M5Stack
  • 添加操纵电机用的操纵杆
  • 总结

本部分所需部件M5Stack Core
搭载了ESP32的Arduino兼容设备
 
Grove I2C电机驱动器
与Grove引脚连接即可使用的电机驱动器
 
ROHM的照度、接近一体型传感器 (RPR-0521RS)
通过发射红外光来测量光强和接近程度。
 
超声波距离传感器 (HC-SR04)
通过发射超声波来测量距离的模块
 
小型电机、车轮等
 
9V电池和电池盒
 

1. 导入智能手机应用程序“Blynk”
我们需要导入名为“Blynk”的应用程序，以便通过智能手机操作用M5Stack制作而成的遥控车。在iOS或Android系统中搜索并安装Blynk应用程序。
 
下载后，打开应用程序，会被要求创建一个帐户，请用您的邮箱等注册并登录。在第一个画面中，会出现“New Project”，需要给它命名并创建新项目。
 
在详细设置中，Device请选择“ESP32 Dev Board”，Connection请选择“WiFi”。然后，将会出现一个空白的项目画面，这就表明智能手机的准备工作完成了。
 
接下来，在要编程的Arduino IDE中，获取Arduino用的Blynk库。从下面的链接下载库并通过图中菜单添加zip文件。
Blynk的Github页面 https://github.com/blynkkk/blynk-library
 
现在，已经做好在手机和Arduino IDE上使用Blynk的准备了。

2. 在Wi-Fi环境下通过智能手机操作M5Stack
我们已经将M5Stack与智能手机关联起来了，下面需要在画面上添加一个操作功能。
当点击Blynk应用程序的画面时，会出现可以从右侧添加的Widget（功能），我们先添加“Button”。
 
在这里，我希望在按下该按钮时能够从M5Stack的扬声器发出嘟嘟声。在按钮的详细设置画面上，OUTPUT选择“Virtual”并指定V1。稍后将在M5Stack上指定V1，所以请记住这里的设置。您还可以选择仅在按下时发送信号的“PUSH”，并设置标签名称（Beep）等。
 
 
左：未按下按钮的状态 右：按下按钮的状态
最后，要获取一个与M5Stack连接的令牌。令牌可以在项目创建时通过e-mail发送，也可通过打开“Project Settings”复制下方的“AUTH TOKEN”。稍后将通过Arduino IDE指定。
 

现在，需要使用Arduino IDE进行编程了。首先，拷贝一个名为“Speaker”的草图示例作为M5Stack的示例。
在该示例中添加以下第3〜9、13〜22、28〜29、36行的内容。在草图的xxxx部分添加前面复制的AUTH TOKEN。yyyy和zzzz是您Wifi环境的用户名和密码。此外，当按下V1按钮时，要能听到嘟嘟声。
  1. [M5Stack_Speaker_Blynk.ino]

  3. #include <M5Stack.h>

  5. #include <WiFi.h>
  6. #include <WiFiClient.h>
  7. #include <BlynkSimpleEsp32.h>

  9. char auth[] = "xxxx”; //输入Blynk应用程序的YourAuthToken
  10. char ssid[] = "yyyy"; //输入Wifi的ID和密码
  11. char pass[] = "zzzz";

  13. #define NOTE_DH2 661

  15. int BEEP_Flag = 0;
  16. BLYNK_WRITE(V1)
  17. {
  18.   BEEP_Flag = param.asInt();
  19.   if(BEEP_Flag == 1){
  20.     M5.Lcd.printf("Blynk wasPressed \r\n");
  21.     M5.Speaker.beep(); //beep
  22.   }
  23.   M5.update();
  24. }

  26. void setup() {
  27.   // Initialize the M5Stack object
  28.   M5.begin();
  29.   
  30.   M5.Lcd.setTextSize(3);
  31.   Blynk.begin(auth, ssid, pass);
  32.     
  33.   M5.Power.begin();
  34.   M5.Lcd.printf("M5Stack Speaker:\r\n");
  35. }

  37. void loop() {
  38.   Blynk.run();
  39.   
  40.   if(M5.BtnA.wasPressed()) {
  41.     M5.Lcd.printf("A wasPressed \r\n");
  42.     M5.Speaker.beep(); //beep
  43.   }
  44.   if(M5.BtnB.wasPressed())
  45.   {
  46.     M5.Lcd.printf("B wasPressed \r\n");
  47.     M5.Speaker.tone(NOTE_DH2, 200); //frequency 3000, with a duration of 200ms
  48.   }
  49.   M5.update();
  50. }
运行此程序后，当Wi-Fi连接完成时，在串口监视器上会显示下列画面。在与智能手机相同的Wifi环境下，将会从Blynk连接M5Stack。当按下屏幕上的按钮时，应该会发出嘟嘟声。
 

3. 添加操纵电机用的操纵杆
现在，我们需要添加一个通过智能手机驱动M5Stack的电机的功能。有现成的“Joystick”（操纵杆）可以用来控制行进方向和旋转速度，我们可以在手机画面上对其进行设置。Joystick的输出为V0，将其输出范围设置为-50到50。
 
最后，需要编写通过Blynk控制M5Stack的程序。将Blynk的描述添加到在上一部分中创建的传感器与电机联动的程序“M5Stack_Near_Dist_Motor.ino”中。下面的第15〜31、96、116行是前面的扬声器所用的部分。在第33〜93、111〜112、123〜126、162〜163行添加了根据Joystick控制电机的描述。
  1. [M5Stack_Near_Dist_Motor_Blynk.ino]

  3. #include <M5Stack.h>
  4. #include <Wire.h>
  5. #include <RPR-0521RS.h>

  7. RPR0521RS rpr0521rs;

  9. #define TRIG 2
  10. #define ECHO 5
  11. int times;
  12. int distance;

  14. #include "Grove_I2C_Motor_Driver.h"
  15. #define I2C_ADDRESS 0x0f

  17. #include <WiFi.h>
  18. #include <WiFiClient.h>
  19. #include <BlynkSimpleEsp32.h>
  20. char auth[] = "xxxx”; //输入Blynk应用程序的YourAuthToken
  21. char ssid[] = "yyyy"; //输入Wifi的ID和密码
  22. char pass[] = "zzzz";

  24. int BEEP_Flag = 0;
  25. BLYNK_WRITE(V1)
  26. {
  27.   BEEP_Flag = param.asInt();
  28.   if(BEEP_Flag == 1){
  29.     M5.Lcd.printf("Blynk wasPressed \r\n");
  30.     M5.Speaker.beep(); //beep
  31.   }
  32.   M5.update();
  33. }

  35. long Speed;
  36. long Speed1, Speed2;
  37. long SpeedL, SpeedR;

  39. //接收操纵杆的数据
  40. BLYNK_WRITE(V0) {
  41.   M5.Lcd.setCursor(10,180);

  43.   long x = param[0].asInt();
  44.   long y = param[1].asInt();
  45.   Speed = sqrt(x*x+y*y);
  46.   if(Speed > 50){
  47.     Speed = 50;
  48.   }
  49.   SpeedR = Speed - Speed1;
  50.   SpeedL = Speed - Speed2;

  52.   if(y >= 0){
  53.     if(x >= 0){
  54.       Speed1 = abs(x);
  55.       Speed2 = 0;
  56.     }else{
  57.       Speed1 = 0;
  58.       Speed2 = abs(x);
  59.     }
  60.     Serial.print("  R:");
  61.     Serial.print(SpeedR); 
  62.     Serial.print("  L:");
  63.     Serial.println(SpeedL); 
  64.     
  65.     Motor.speed(MOTOR1, -SpeedR);
  66.     Motor.speed(MOTOR2, SpeedL);
  67.     
  68.     M5.Lcd.print("Fwd!");
  69.     
  70.     delay(500);
  71.     Motor.speed(MOTOR1, 0);
  72.     Motor.speed(MOTOR2, 0);
  73.     
  74.   }else{
  75.     if(x >= 0){
  76.       Speed1 = abs(x);
  77.       Speed2 = 0;
  78.     }else{
  79.       Speed1 = 0;
  80.       Speed2 = abs(x);
  81.     }
  82.     Serial.print("  -R:");
  83.     Serial.print(SpeedR);
  84.     Serial.print("  -L:");
  85.     Serial.println(SpeedL);
  86.     
  87.     Motor.speed(MOTOR1, SpeedR);
  88.     Motor.speed(MOTOR2, -SpeedL);
  89.     
  90.     M5.Lcd.print("Back!");
  91.     delay(500);
  92.     Motor.speed(MOTOR1, 0);
  93.     Motor.speed(MOTOR2, 0);
  94.   }
  95. }

  97. void setup() {
  98.   Blynk.begin(auth, ssid, pass);
  99.   Serial.begin(115200);
  100.   while (!Serial);
  101.   
  102.   byte rc;  
  103.   rc = rpr0521rs.init();
  104.   
  105.   pinMode(TRIG, OUTPUT);
  106.   pinMode(ECHO, INPUT);

  108.   Motor.begin(I2C_ADDRESS);

  110.   M5.begin();
  111.   M5.Lcd.setTextSize(4);
  112.   Wire.begin(21,22);
  113.   M5.Lcd.setCursor(10,0);
  114.   M5.Lcd.println(ssid);
  115. }

  117. void loop() {  
  118.   Blynk.run();
  119.   
  120.   byte rc;
  121.   unsigned short ps_val;
  122.   float als_val;
  123.   byte near_far;

  125.   M5.lcd.clear();
  126.   M5.Lcd.setCursor(10,0);
  127.   M5.lcd.print("M5 Blynk");
  128.   M5.Lcd.setCursor(10,50);
  129.   
  130.   rc = rpr0521rs.get_psalsval(&ps_val, &als_val);
  131.   if (rc == 0) {
  132.     Serial.print(F("RPR-0521RS (Proximity)     = "));
  133.     Serial.print(ps_val);
  134.     Serial.print(F(" [count]"));
  135.     near_far = rpr0521rs.check_near_far(ps_val);
  136.     if (near_far == RPR0521RS_NEAR_VAL) {
  137.       Serial.println(F(" Near"));
  138.       M5.lcd.print("Near!");
  139.     } else {
  140.       Serial.println(F(" Far"));
  141.       M5.lcd.print("Far!");  
  142.     }
  143.   }

  145.   digitalWrite(TRIG, HIGH);  // 发射超声波
  146.   delayMicroseconds(10);
  147.   digitalWrite(TRIG, LOW);
  148.   times = pulseIn(ECHO, HIGH);  // 接收超声波
  149.   distance = (int)(times * 0.017);
  150.   Serial.println(distance);  // 在显示器上显示
  151.   M5.Lcd.setCursor(10, 100);
  152.   M5.Lcd.print(distance);

  154.   if ( ((distance > 0) and (distance < 6)) or (near_far != RPR0521RS_NEAR_VAL) ) {
  155.     Motor.speed(MOTOR1, 50);
  156.     Motor.speed(MOTOR2, -50);
  157.     delay(800);
  158.     Motor.speed(MOTOR1, 50);
  159.     Motor.speed(MOTOR2, 50);
  160.     M5.Lcd.setCursor(10,150);
  161.     M5.lcd.print("Danger!");
  162.     delay(800);
  163.   } else {
  164.     Motor.speed(MOTOR1, 0);
  165.     Motor.speed(MOTOR2, 0);
  166.   }
  167.   delay(300);
  168. }
下面我们来尝试操纵遥控车。和前面一样，进入相同的Wi-Fi环境，连接M5Stack。当您前后左右移动操纵杆时，M5Stack是否跟着做出了相应的移动？当遥控车接近墙壁或者要从桌子上掉落下来时，和上次一样，它会避开。
 

4. 总结
在本系列连载中，为您介绍了使用M5Stack自动驾驶遥控车的制作过程。
使用可以从智能手机连接M5Stack的应用程序Blynk，还能轻松添加通过智能手机操纵遥控车的功能。我们成功地使按钮与M5Stack扬声器联动起来，并实现了通过操纵杆的控制而前后左右移动。
Blynk有各种各样的Widget，还可以根据M5Stack的传感器等来添加更多不同的功能，这样会更有趣。比如，您还可以考虑怎样将物体的接近程度以及温湿度传感器测量到的值等在显示器上显示出来。
盼望您大胆尝试，让您的创意变成现实！感谢您阅读本系列文章！

来源：/techclass.rohm
  • 上一篇文章： 吊打stm32 ！在开发者眼中ESP32到底有多强？

  • 下一篇文章： PIC、AVR、51、STM32单片机有什么区别？
    •    
    [注：标题搜索比内容搜索快]
    【发表评论】【告诉好友】【打印此文】【关闭窗口】
     最新5篇热点文章
  • TEMP[126]

  • SAE001[93]

  • 高光谱成像基本原理[68]

  • 蒸汽火车解剖图[79]

  • 星球大战死星解剖图集 star wa…[86]

    		•
    		　
     最新5篇推荐文章
  • 外媒：正在唤醒中国的习近平[340]

  • 中国反伪科学运动背后的CIA黑手…[517]

  • [转载]袁隆平真言：中国最大的…[698]

  • 台专家：当年我们造IDF时 大陆…[591]

  • 旅日华人：中国严重误判日本民…[596]

    		•
    		　
     相 关 文 章
  • 吊打stm32 ！在开发者眼中ESP3…[30]

    		•

      网友评论：（只显示最新10条。评论内容只代表网友观点，与本站立场无关！）
        没有任何评论
    | 设为首页 | 加入收藏 | 联系站长 | 友情链接 | 版权申明 | 管理登录 | 
    版权所有 Copyright© 2003 晨光科技        站长：璀璨星辰        页面执行时间：367.19毫秒
    Powered by：MyPower Ver3.5